Excel中读取单元格填充色RGB值的多种VBA实现方法

在Excel中，并没有直接的函数可以像调用RGB()函数那样来“确定”或“读取”单元格填充色的RGB值。最简单的方法是按照以下步骤操作：

1. 选择使用要检查的颜色设置格式的单元格。
2. 显示功能区的选项卡。
3. 单击“填充颜色”工具右侧的“字体”组中的向下箭头。Excel 显示一个小的调色板和一些其他选项。
4. 选择更多颜色。Excel 将显示颜色对话框。
5. 确保显示自定义选项卡。（参见图 1）
6. 在对话框的底部，您可以看到单元格中颜色的红色、绿色和蓝色分量的各个值。
7. 点击 OK 完成后。

如果我们需要更频繁地获取值，那么可以通过VBA来创建自定义函数。例如，如果要返回 RGB 颜色的传统六字符十六进制代码，则可以使用以下非常简单的宏：

Function getRGB1(rcell) As String
    Dim sColor As String
    sColor = Right("000000" & Hex(rcell.Interior.Color), 6)
    getRGB1 = Right(sColor, 2) & Mid(sColor, 3, 2) & Left(sColor, 2)
End Function

此宏查看所引用的任何单元格的内部颜色，将颜色的十六进制值按正确的顺序排列，并将字符串返回到 Excel。要使用该函数，您只需在工作表中调用它，并按以下方式引用一个单元格：

=getRGB1(B4)

但是，我们可能不需要 RGB 颜色的传统十六进制代码。如果要获取每种颜色的十进制值，则以下宏将返回：

Function getRGB2(rcell) As String
    Dim C As Long
    Dim R As Long
    Dim G As Long
    Dim B As Long
    C = rcell.Interior.Color
    R = C Mod 256
    G = C \ 256 Mod 256
    B = C \ 65536 Mod 256
    getRGB2 = "R=" & R & ", G=" & G & ", B=" & B
End Function

该调用方式与 上述getRGB1 宏相同，返回一个字符串，例如“R=255， G=204， B=0”。您还可以进一步修改宏，使其根据您设置的参数返回单个值：

Function getRGB3(rcell As Range, Optional opt As Integer) As Long
    Dim C As Long
    Dim R As Long
    Dim G As Long
    Dim B As Long

    C = rcell.Interior.Color
    R = C Mod 256
    G = C \ 256 Mod 256
    B = C \ 65536 Mod 256

    If opt = 1 Then
        getRGB3 = R
    ElseIf opt = 2 Then
        getRGB3 = G
    ElseIf opt = 3 Then
        getRGB3 = B
    Else
        getRGB3 = C
    End If
End Function

要使用宏，只需将第二个参数添加到工作表中使用的函数中，指定所需的内容：

=getRGB3(B4,1)

如果第二个参数为 1，则函数仅返回红色值。如果指定第二个参数 2，则返回绿色值，3 返回蓝色值。第二个参数的任何其他值（或者如果完全省略它）将返回内部颜色的完整十进制值。

getRGB3函数的核心在于它巧妙地利用了VBA的模除（Mod）和整除（\）运算来从Excel单元格的Interior.Color属性中提取出RGB各通道的值。通过对这些基本操作的深入理解与运用，我们能够以简洁而高效的方式实现复杂的数据处理逻辑。此外，函数中的可选参数opt为函数的使用提供了额外的灵活性，使得它能够满足不同场景下的需求，无论是需要整体颜色值还是单独的颜色通道值。

以上三种getRGB函数的演示：

总的来说，getRGB3函数是数据处理与可视化领域中的一个实用工具，它不仅简化了Excel单元格颜色数据的处理流程，还通过其灵活的设计为开发者提供了更多可能性。